Существует ли способ видеть все песни в iTunes, который опцию “Skip when shuffling” включили?

Если Вы находитесь на Mac OS X, Вы могли бы попробовать следующий AppleScript. Это находит все unshuffable дорожки источника, который Вы выбираете, и помещает их в новый, “немой” плей-лист.

Если Вы находитесь в Windows, то, возможно, Вы могли адаптировать 'логику' этого сценария на любой язык COM, который Вы имеете под рукой. См. Windows Solutions section AppleScripts Doug для iTunes.

У меня нет iPod, таким образом, я не мог протестировать его с дорожками iPod, но он работал для нахождения "unshuffable" дорожек в моей нормальной библиотеке.

-- Pick a source (main library/iPod)
tell application "iTunes" to set allSources to sources
set possibleSources to {}
repeat with aSource in allSources
    using terms from application "iTunes"
        if kind of aSource is in {library, iPod, device} then -- shared library, unknown
            set end of possibleSources to contents of aSource
        end if
    end using terms from
end repeat
set sourceStrs to {}
set n to 1
repeat with aSource in possibleSources
    using terms from application "iTunes"

        tell aSource to set end of sourceStrs to "" & n & ". " & name & " (" & id & "/" & persistent ID & ")"
    end using terms from
end repeat

choose from list sourceStrs without multiple selections allowed
set theSourceStr to first item of result
text 1 through ((offset of "." in theSourceStr) - 1) of theSourceStr as integer
set theSource to item result of possibleSources

-- Make a new (dumb) playlist to hold the found tracks
tell (current date) to ¬
    set playlistName to "Unshuffables on " & short date string & " at " & time string
using terms from application "iTunes"
    tell theSource to set unshuffablesPlaylist to make new playlist with properties {name:playlistName}
end using terms from

-- Find all "unshuffable" tracks and add them to the new playlist.
using terms from application "iTunes"
    repeat with aPlaylist in library playlists of theSource
        duplicate (tracks of aPlaylist whose shufflable is false) to unshuffablesPlaylist
    end repeat
end using terms from