Вопросы Теги

В OSX я могу запустить, расположить и масштабировать приложение с помощью applescript/automator?

Я надеюсь автоматизировать запуск своей рабочей области. Я использую несколько приложений, тщательно расположенных через два монитора, и я хотел бы смочь запустить свои предпочтенные разметки одним щелчком

Я знаю, как запустить несколько приложений с automator сценарием, теперь я просто должен смочь поместить приложения, где они принадлежат на экране.

Большое спасибо.

2
задан 14.03.2011, 13:51

2 ответа

Это, в то время как возможно, может быть немного слишком трудно, чтобы сделать со сценарием. Вот частичный демонстрационный сценарий, который восстанавливает Firefox и окна iTunes (адаптированный из сценария, найденного здесь.)

property numFFWindows : 0
property FFPos : {}
property FFSize : {}
property iTunesPos : {}
property iTunesSize : {}

display dialog "Set Window Position or Save Window Position?" buttons {"Restore", "Save"} default button "Restore"
set theResult to result

tell application "System Events"
    if (button returned of theResult is "Restore") then
        -- Restore Settings
        if (numFFWindows > 0) then
            tell process "Firefox"
                repeat with i from 1 to numFFWindows
                    set position of window i to (item i of FFPos)
                    set size of window i to (item i of FFSize)
                end repeat
            end tell
        end if
        if (iTunesPos is not {0, 0}) then
            tell process "iTunes"
                set position of window 1 to iTunesPos
                set size of window 1 to iTunesSize
            end tell
        end if
    else
        -- Save Settings
        tell process "Firefox"
            set numFFWindows to count windows
            set FFPos to {}
            set FFSize to {}
            repeat with i from 1 to numFFWindows
                set end of FFPos to (position of window i)
                set end of FFSize to (size of window i)
            end repeat
        end tell
        tell process "iTunes"
            set iTunesPos to position of window 1
            set iTunesSize to size of window 1
        end tell
    end if
end tell

Я предлагаю, чтобы Вы посмотрели на эту утилиту для большей гибкости:

http://cordlessdog.com/stay/

1
ответ дан 12.12.2019, 00:17

Вот является другое использование в качестве примера Applescript:

tell application "Finder"
    set {0, 0, dtw, dth} to bounds of window of desktop
end tell

tell application "Finder"
    reopen
    activate
    try
        set bounds of window 1 to {0, 22, dtw / 2, dth / 2}
    end try
end tell

tell application "Safari"
    reopen
    activate
    try
        set bounds of window 1 to {0, 22, dtw, dth}
    end try
end tell

tell application "Terminal"
    reopen
    activate
    try
        set position of window 1 to {0, 22}
        set size of window 1 to {dtw / 2, dth - 22}
    end try
end tell

tell application "TextEdit"
    reopen
    activate
    try
        set bounds of window 1 to {dtw / 2, 22, dtw, dth}
    end try
end tell

Работа с несколькими мониторами требует слишком большого колдовства все же.

SizeUp имеет отдельные действия для перемещения окна к следующему монитору и установке границ для окон.

0
ответ дан 12.12.2019, 00:17

Теги

Похожие вопросы