Когда я использую iTunes для создания файлов Mp3 из песен, я купил, iTunes также добавляет их к моей библиотеке, и я получил их дважды. То, как я могу препятствовать тому, чтобы iTunes добавил, преобразовало Mp3s в библиотеку во-первых?
Править:
Я использую iTunes на Mac OS X
EDIT2:
Ответ Chris Johnsen довольно хорош и стоит щедрости. Однако я также попробовал этот сценарий, на который Chris указал на меня, и это еще лучше, и я буду использовать это с этого времени. Спасибо люди.
Если Вы соглашаетесь с временным наличием преобразованных дорожек в Вашей библиотеке iTunes, Вы могли использовать AppleScript, чтобы преобразовать дорожку, удалить ссылку на преобразованную дорожку и наконец переместить преобразованный файл, где когда-либо Вам нравится.
Плоскость AppleScript имеет мало возможности гладкого UI, но следующий сценарий мог бы сделать то, что Вы хотите. Вставьте его в Редактор сценариев (или Редактор AppleScript на Снежном) и сохраните его как “комплект приложений” (“приложение” на Снежном). Для использования его, настроил настройки преобразования (Настройки Импорта) в iTunes, выберите некоторые дорожки в iTunes, затем отбросьте папку на сохраненном приложении. Обратите внимание, что недавно преобразованные файлы перезапишут существующие ранее файлы в отброшенной папке (если их имена будут идентичны). Вероятно, лучше отбросить пустые папки, если Вы не уверены, что хотите любые перезаписи, которые Вы могли бы получить. Вы могли бы даже вытащить некоторые теги ID3v2 из процесса (я сделал в некотором тестировании, но это зависит от того, что iTunes решает сделать).
on run
display dialog "Drop a folder on this application to convert iTune's selected tracks and place them the dropped folder." & return & return & "The converted files will be whatever is selected in iTunes “Import Settings”." with title "About"
return
-- Test invocation:
"/tmp/convert_to_external"
alias POSIX file result
open {result}
end run
on open theItems
if length of theItems is 0 then
display dialog "No items dropped? Only a single, plain folder should be dropped." with title "Error: Drop Only a Single Folder"
return
end if
if length of theItems is greater than 1 then
display dialog "Too many items have been dropped. Only a single, plain folder should be dropped." with title "Error: Drop Only a Single Folder"
return
end if
set theItem to first item of theItems
set info to info for theItem
if not folder of info or package folder of info then
display dialog "“" & POSIX path of theItem & "” is not a plain folder. Only a single, plain folder should be dropped." with title "Error: Drop Only a Single Folder"
return
else
|convert iTunes selection into folder|(theItem)
end if
end open
to |convert iTunes selection into folder|(folderRef)
try
do shell script "test -d " & quoted form of POSIX path of folderRef
on error m
display dialog "Destination (" & destinationForShell & ") not accessible?" & return & m
return
end try
tell application "iTunes"
set trackList to selection
repeat with selectedTrack in trackList
try
set convertedTrack to my convertTrack(selectedTrack)
set convertedFile to location of convertedTrack
my deleteTrackReference(convertedTrack) -- only delete the iTunes ref, not the track's file
my moveItemToFolder(convertedFile, folderRef)
on error m
tell me to display dialog m with title "Error During Conversion/Removal/Move" -- giving up after 30
end try
end repeat
end tell
end |convert iTunes selection into folder|
to convertTrack(aTrack)
if class of aTrack is list then error "Must pass a single track."
using terms from application "iTunes"
set questionTimeout to 10
set conversionTimeout to 600
display dialog "About to start conversion of “" & name of aTrack & "”. Select a timeout in seconds for the conversion (conversion will auto-start in " & questionTimeout & " seconds):" default answer conversionTimeout with title "Conversion Time Limit" giving up after questionTimeout
try
set conversionTimeout to (text returned of result) as number
end try
set convertedTrack to missing value
with timeout of conversionTimeout seconds -- conversion may take longer than the deafult 120 second AppleEvent RPC timeout
try
set convertedTrack to convert aTrack
on error
error "Error while converting track."
end try
end timeout
if convertedTrack is not missing value then return first item of convertedTrack
error "Abandoning track conversion after timeout." & return & m
end using terms from
end convertTrack
to deleteTrackReference(aTrack)
try
tell application "iTunes" to set mainLibrary to ¬
first library playlist of (first source whose kind is library)
on error
error "Unable to find main library playlist object."
end try
using terms from application "iTunes"
try
set convertedTrackInMainLibrary to ¬
(first track of mainLibrary whose database ID is (get database ID of aTrack))
on error
error "Unable to find track object in main library playlist."
end try
try
delete convertedTrackInMainLibrary -- deletes the reference, not the actual file
on error
error "Unable to delete track from main library playlist."
end try
end using terms from
end deleteTrackReference
to moveItemToFolder(itemRef, folderRef)
set itemPath to POSIX path of itemRef
set folderPath to POSIX path of folderRef
try
do shell script "mv " & quoted form of itemPath & " " & quoted form of folderPath
on error m
error "Unable to move item (" & itemPath & ") to destination (" & folderPath & "):" & return & m
end try
end moveItemToFolder
Насколько я знаю, нет никакого способа сделать это. Вы могли бы хотеть использовать другое приложение, как Quicktime или AudialHub, чтобы сделать преобразование вместо этого. Вы хотите сохранить оригинал, или новый файл в iTunes? Можно создать умные плей-листы, чтобы помочь Вам собраться, любой в единственный список для удаления их всех из библиотеки за один шаг (выберите - удаляют в OS X).
В зависимости от того, как часто Вы делаете это, Вы могли экспортировать плей-лист в Диск MP3. Необходимо будет записать диск каждый раз, когда но перезаписываемое могло бы решить ту проблему.
Шаги:
1) Создайте плей-лист песен, которые Вы хотите
2) Щелкните правой кнопкой по плей-листу и выберите "Burn playlist to Disc"
3) В опциях, которые подходят, выберите MP3 CD и нажмите запись.
4) Песни будут записаны к диску в формате MP3.
5) Захватите песни от диска, когда он монтируется в средстве поиска, делают с ними, что Вы будете.
Это действительно включает несколько утомительный шаг записи CD, но это ничего не требует третье лицо и является функцией в iTunes.
Переместите созданные файлы MP3 в другой каталог за пределами дерева, которое iTunes просканирует для нового содержания.
Я предполагаю, что Вы используете что-то другое, чем MP3 как Ваш основной формат аудио, поэтому создайте пакетное задание для перемещения любого содержания MP3 от дерева каталогов iTunes в отдельное местоположение.
Например, использовать ROBOCOPY.EXE
сделать это:
c:\windows\robocopy c:\itunes-path c:\mp3-files *.mp3 /s /zb /mov /xo
Эта команда переместит файлы MP3 во все подкаталоги кроме того, если цель уже будет существовать, и источник является более старым. Можно добавить /mot:5
в конец, чтобы иметь его, повторяются каждые 5 минут.
Править: Я предложил некоторые общие решения, но кажется, что iTunes не имеет необходимых функций ни одного из них, таким образом, я удалил предложения.