Действительно ли возможно экспортировать историю чата Skype v4 в некоторый читаемый формат простого текста?
(.txt, .xml, .html
)
С другой стороны, действительно ли возможно копировать/восстанавливать историю разговора по скайпу?
(Я не возражал бы против резервного копирования на Gmail, или на читаемый формат простого текста).
Я нашел многочисленные инструменты в Интернете и даже судил некоторых из них, но они, кажется, не работают.
См. сценарий, представленный здесь: Сохраните историю Разговора по скайпу.
Вот код:
' Define global variables
Dim oFSO, chat_file, folder_to_save
' Directory where You want to save history (you can modify it)
' Now it is relative, so it will be created where Your *.vbs script runs
folder_to_save = "SkypeChatHistory"
line_count = 0
' Create FSO
Set oFSO = CreateObject("Scripting.FileSystemObject")
set_next_free_dir()
' Connect to Skype API via COM
Set oSkype = WScript.CreateObject("Skype4COM.Skype", "Skype_")
' Open skype, if it is not running
If Not oSkype.Client.IsRunning Then
oSkype.Client.Start()
End If
WScript.Echo "Skype history will be saved. Found " & oSkype.Chats.Count & " chat group."
' Iterate chats
For Each oChat In oSkype.Chats
names = ""
' First name is You, so it is unnecessary to keep
no_1st_flag = TRUE
For Each oUser In oChat.Members
If no_1st_flag Then
no_1st_flag = FALSE
Else
names = names & "_" & oUser.FullName
End If
Next
get_file("chat" & names & ".txt")
chat_file.WriteLine(vbNewLine & "==== CHAT HISTORY (" & Replace(names, "_", "") & ") ====" & vbNewLine)
line_count = line_count + oChat.Messages.Count
' Fix by an anonymous commenter
If oChat.Messages.Count > 0 Then
For Each oMsg In oChat.Messages
' Fix by Vadim Kravchenko
On Error Resume Next
chat_file.WriteLine(oMsg.FromDisplayName & " (" & oMsg.Timestamp & "): " & oMsg.Body)
Next
End If
chat_file.Close
Next
WScript.Echo "Backup was finished (" & line_count & " line saved). You can find your chats in: ./" & folder_to_save
' Garbage collection
SET chat_file = NOTHING
SET folder_to_save = NOTHING
SET oFSO = NOTHING
SET oSkype = NOTHING
' Access to a file given by name
Sub get_file(file_name)
' Parameter fix by: rommeech
Set chat_file = oFSO.OpenTextFile(folder_to_save & "/" & file_name, 8, True, -1)
End Sub
' Find an appropriate directory the logs to save, however, to avoid collision with former dirs
Sub set_next_free_dir()
If oFSO.FolderExists(folder_to_save) Then
ext = 1
While oFSO.FolderExists(folder_to_save & "_" & ext) And ext < 100
ext = ext + 1
Wend
folder_to_save = folder_to_save & "_" & ext
End If
oFSO.CreateFolder(folder_to_save)
End Sub
Просто сохраните его как .vbs
файл и выполненный это. Затем в первый раз, Skype спросит Вас о разрешении соединить API Skype, поэтому просто нажмет "OK". После этого это создаст названную папку SkypeChatHistory
и некоторые файлы в нем, которые должны иметь Вашу историю чата.
Существует опция экспортировать историю Skype в CSV и т.д. от Вашей страницы Account на Skype.com.
это - причина, почему я все еще использую Skype 3.
что они думали, когда они удалили команду/htmlhistory???
с Skype 4 я боюсь, что единственные опции являются commecial программами, такими как Pamela для Skype (запись чата не доступна в бесплатной версии).
что касается резервного копирования и восстановления история чата, это довольно легко:
Найдите папку Application Data\Skype\(Ваше имя пользователя) и скопируйте его в другое местоположение, такое как CD или DVD-ROM.
Для восстановления файлов истории просто копируют файлы назад в ту папку.
Программное обеспечение, которое позволяет записывать вызовы и хранилище, записало историю/передачи файлов вызовов/чата на Ваш адрес электронной почты - http://skype2email.com
Skype2email является коммерческой программой с бесплатной демонстрационной версией 14 дней.
Отказ от ответственности: Я работал над этой программой.
Я думаю, что существует более изящный способ сохранить Ваши чаты, и вызовы затем отправляют его в электронную почту. Например, использование Устройства записи Skype позволяет Вам сохранить все это к онлайн-хранилищу, а также добавить такие функции как полнотекстовый поиск, играть Ваши вызовы онлайн и многих других хорошие функции. Я думаю, что это действительно поможет Вам с Вашей проблемой.
Самая легкая вещь сделать, если Вы просто хотите передать историю другому компьютеру, состоит в том, чтобы последовать совету Skype здесь: https://support.skype.com/en/faq/FA10649/Can-I-transfer-my-chat-history-from-one-computer-to-another? frompage=search&q=chat+history&fromSearchFirstPage=false. То, что Вы делаете, отметить Ваши переговоры как Непрочитанные, и они переданы другому компьютеру, когда Вы регистрируетесь к нему в следующий раз.
Просто необходимо перейти к пользователю основная папка как в win7: C:\Users[your_user]\AppData\Roaming\Skype
Помните, что папка "AppData" скрыта, таким образом, Вам, возможно, придется выбрать опцию показать скрытые папки.
Затем найдите папку с именем пользователя Вашей учетной записи в скайпе и скопируйте его в новый ПК... все Ваши чаты и значки контактов, и и т.д. будет скопирован в новый компьютер.
Просто откройте новое окно чата с контактом, для кого Вы хотите сохранить историю чата. Введите "/историю" (без кавычек) в окне чата. После того как история заполняется, выберите/выделите часть текста с Вашим курсором мыши. Затем (в Windows) нажимают "Ctrl+A" на Вашей клавиатуре. После того как все выделяется, нажмите "Ctrl+C". Откройте Microsoft Word (или подобное программное обеспечение обработки текста, как Устройство записи OpenOffice.org) и нажмите "Ctrl+V" на своей клавиатуре. Сохраните файл на своем жестком диске или Карте памяти, и вуаля: у Вас есть полная запись Вашей истории чата.