Сортировка электронных писем без К: теги в Outlook

Если у Вас есть Exchange Server, и это является все внутренним, то не, не возможно сказать, кому было послано электронное письмо.

Если это было отправлено от внешнего почтового сервера или почти какого-либо почтового сервера кроме Exchange: В заголовках исходная полученная строка должна иметь для; который правила Outlook могут искать (только сторона клиента). Просто установите условие "с определенными словами в заголовке сообщения" для адреса электронной почты списка рассылки.

Exchange не добавляет стандартные почтовые заголовки, если он не оставляет Exchange, который несовместим с RFC, но снова, это - Microsoft.

я предлагаю Вас, бегунок делает правило, которые перемещают все электронные письма, в которых Вы находитесь К, или CC к папке и этой папке становится основным для Вас, и все другие письма становятся в другом папками

Таким образом, Вы ищете, "Где мое имя не находится в К, или правило" полей Cc, но это - одно правило, которое они не имеют в мастере. Я надеюсь, что имею то право.

Я не знаю ни о каких подобных дополнениях, однако это возможно к самокрутке. Эта статья MSDN показывает, как получить доступ к Outlook 2007 и создать дополнение.

Или Вы могли сделать это в макросах VBA, на самом деле... здесь этот я записал, сделает то, что Вы хотите, просто настраиваете константы к своей симпатии. В Outlook открывают макро-редактора (Alt+F11) и вставляют это в модуль ThisOutlookSession. Если Вы не добавили макросы там прежде, это должно быть пусто.

Уже необходимо будет включить макросы, если не, с помощью меню Tools-> Macros-> безопасность. Если установлено на 'Предупреждениях для всех макросов' затем Вам предложат каждый раз, когда Вы открываете Outlook, который прекрасен. Вновь откройте Outlook после сохранения макроса.

'# [Outlook VBA custom mail mover by keyboardMonkey]
'# Checks new email if YOUR_NAME does not appear in the TO or CC list.
'# moves the message to DESTINATION_FOLDER.
'# Note: DESTINATION_FOLDER must be a child of the Inbox node, not a sibling.

Const YOUR_NAME As String = "Wesley"
Const DESTINATION_FOLDER As String = "testfolder"

'// hook into the outlook items events
Public WithEvents myOlItems As Outlook.Items


Public Sub Application_Startup()

    ' get the inbox item collection
    Set myOlItems = Outlook.Session.GetDefaultFolder(olFolderInbox).Items

End Sub

'// called on mail item add
Private Sub myOlItems_ItemAdd(ByVal Item As Object)

    If TypeName(Item) = "MailItem" Then

        ' get strongly typed object
        Dim mymail As MailItem
        Set mymail = Item

        ' flags if our name appears in each of the fields
        Dim name_in_to As Boolean
        Dim name_in_cc As Boolean
        name_in_to = InStrB(1, mymail.To, YOUR_NAME) > 0
        name_in_cc = InStrB(1, mymail.CC, YOUR_NAME) > 0

        '#Uncomment below to show mail item details
        ' MsgBox (mymail.Subject + " has me in TO: " + Str(name_in_to) + " and CC: " + Str(name_in_cc))

        ' are we mentioned in the header?
        If (Not name_in_to And Not name_in_cc) Then

            ' start with each main mapi folder
            Dim idx As Integer
            For idx = 1 To Outlook.Session.Folders.Count - 1

                ' recurse into subfolders
                Dim dest As Outlook.MAPIFolder
                Set dest = GetFolder(Outlook.Session.Folders.Item(idx), DESTINATION_FOLDER)

                ' we found our destination!
                If Not (dest Is Nothing) Then
                    mymail.Move dest
                    Exit For
                End If

            Next

        End If

        ' house cleaning
        Set mymail = Nothing

    End If

End Sub

'// to iterate is human. to recurse, divine
Private Function GetFolder(parent As Folder, name As String) As Outlook.MAPIFolder
    Dim idx As Integer
    Dim res As Object
    For idx = 1 To parent.Folders.Count
        Set res = GetFolder(parent.Folders.Item(idx), name)
        If Not res Is Nothing Then
            Set GetFolder = res
            Exit For
        End If
    Next
    If (parent.name = name) Then
        Set GetFolder = parent
    End If
End Function